u-boot-2009.08在mini2440上的移植 增加nand flash功能

移植环境

1，主机环境：VMare下CentOS 5.5 ，1G内存。

2，集成开发环境：Elipse IDE

3，编译编译环境：arm-linux-gcc v4.4.3，arm-none-eabi-gcc v4.5.1。

4，开发板：mini2440，2M nor flash，128M nand flash。

5，u-boot版本：u-boot-2009.08

目前u-boot中还没有对2440上Nand Flash的支持，也就是说要想u-boot从Nand Flash上启动得自己去实现了。在做u-boot移植的时候，多数人使用的是Nand flash启动或Nar Flash启动。这样u-boot就只能在Nand flash或Nor flash。那么我们如何让我们的u-boot在Nand flash或Nor flash都能使用。

3.1，Nand flash或Nor flash双启动原理

首先，看一下我们熟悉的u-boot启动的时候执行的一段程序，这段程序一般存放在Nand flash中或Nor flash中。我们所说的Nand flash启动或Nor flash启动主要是涉及到一段搬移代码。这段搬移代码的功能是u-boot自己把自己搬移到内存中执行。如下是Nor flash启动中的这段搬移代码(这里以s3c2410为例)

　　relocate:                        /* relocate U-Boot to RAM */
　　adr r0, _start        /* r0 <- current position of code */
　　ldr r1, _TEXT_BASE        /* test if we run from flash or RAM */
　　cmp r0, r1                        /* don't reloc during debug */
　　beq stack_setup
　　ldr r2, _armboot_start
　　ldr r3, _bss_start
　　sub r2, r3, r2                /* r2 <- size of armboot */
　　add r2, r0, r2                /* r2 <- source end address */
　　copy_loop:
　　ldmia r0!, {r3-r10}                /* copy from source address [r0] */
　　stmia r1!, {r3-r10}                /* copy to target address [r1] */
　　cmp r0, r2                /* until source end addreee [r2] */
　　ble copy_loop
　　#endif        /* CONFIG_SKIP_RELOCATE_UBOOT */
　　#endif

上面这段代码就是把u-boot搬移到内存。而不同的启动方式区别也就在这段代码上，如果我们这里是Nand flash启动的话我们也需要写相同功能的代码，不同的是对于Nand的操作和Nor的操作是完全不同的，选择Nor flash启动是将Nor flash映射到片选0上也就是0x0地址而选择Nand flash启动则是将CPU的片内RAM(4K)映射到0地址，通过Nand flash控制器操作Nand flash。我们这里讨论如何实现Nand 和 Nor双启动。下面我们看看这两种启动的映射关系。

同时我们可以看到： 总线宽度和等待控制寄存器：

 在系统重启时会扫描BWSCON的状态，而BWSCON的其他位的初始状态都是0，只有DW0(BWSCON[2:1])的值由OM[1:0]来决定，通过上面的2个图我们可以发现，我们可以通过判断BWSCON的第2位、第3位   {DW0（BWSCON[2:1])}的值，判断是Nor flash启动还是Nand Flash启动。可以启动代码之前添加如下代码，来判断是Nor flash启动还是Nand Flash启动。

 # define BWSCON   0x48000000
        ldr r0,=BWSCON
        ldr r0,[r0]
        and r0,r0,#6
        cmp  r0, #0 
        bne  relocate

 ///////////////////////////////////////////////////
     //nand_boot
  //Nand 搬移代码
////////////////////////////////////////////////////

  relocate：
       //nor_boot
      //Nor 搬移代码
////////////////////////////////////////////////////

有了上面这段代码，就可以实现双启动了，只要再适当的添加对应的功能我们的uboot就完成了

 3.2，为u-boot增加对nand flash支持实际操作

【1】修改代码重定向部分，增加Nor flash 和Nand flash 双启动

修改cpu/arm920t/start.S文件，为使u-boot从Nand Flash启动，需要将下面注释掉的CPU和DRAM初始化部分还原。

用gedit打开cpu/arm920t/start.S，定位到199行附近，找到如下代码

//#ifndef CONFIG_SKIP_LOWLEVEL_INIT
 //bl cpu_init_crit
//#endif

将注释掉的这段代码恢复，修改如下：

#ifndef CONFIG_SKIP_LOWLEVEL_INIT
 bl cpu_init_crit
#endif

Tekkaman Ninja从2009.08 开始就在启动时增加了启动时检测自身是否已经在SDRAM中(通过OpenJTAG载入)，以及芯片是Norboot还是Nandboot的机制，来决定代码重定向的方式，使得编译出的bin文件可以同时烧入Nand Flash和Nor flash，以及被OpenJTAG载入进行调试。至于这部分的原理，在Tekkaman Ninja的文章《在U-boot下实现自动识别启动Flash的原理(针对S3C24x0) 》 http://www.linuxidc.com/Linux/2011-09/43094.htm 中有详细叙述。这部分代码修改后结果如下：

(1)判断当前代码位置，如果在内存，直接跳到stack_setup

//#ifndef CONFIG_SKIP_RELOCATE_UBOOT
//relocate: /* relocate U-Boot to RAM */
/***************** Check the code position begain*******************************/
 adr r0, _start  /* r0 <- current position of code   */
 ldr r1, _TEXT_BASE  /* test if we run from flash or RAM */
 cmp     r0, r1          /* don't reloc during debug  */
 beq     stack_setup
/****************** Check the code position end ********************************/

(2)如果不是在代码当前位置不再内存中，就判断启动的Flash：Nand 或者Nor
/***************** Check the boot flash begain **********************************/
# define BWSCON  0x48000000
        ldr r0,=BWSCON
        ldr r0,[r0]
        ands r0,r0,#6
        cmp  r0, #0 
        bne  relocate

 /* recovery  */
 ldr r0, =(0xdeadbeef)
 ldr r1, =( (4<<28)|(3<<4)|(3<<2) )
 str r0, [r1]
/***************** check the boot flash end ************************************/
(3)如果判断是在Nand Flash中启动的话，那么nand  Flash搬移代码如下：
定义u-boot在nand flash中存放的长度为#define LENGTH_UBOOT 0x60000，可以方便修改u-boot因为裁剪和增添大小的改变而占的长度。

// copy U-Boot to RAM  form   Nand Flash

/***************** NAND BOOT start *************************************************/

#define LENGTH_UBOOT 0x60000
#define NAND_CTL_BASE 0x4E000000

#ifdef CONFIG_S3C2440
/* Offset */
#define oNFCONF 0x00
#define oNFCONT 0x04
#define oNFCMD 0x08
#define oNFSTAT 0x20

 @ reset NAND
 mov r1, #NAND_CTL_BASE
 ldr r2, =( (7<<12)|(7<<8)|(7<<4)|(0<<0) )
 str r2, [r1, #oNFCONF]
 ldr r2, [r1, #oNFCONF]

 ldr r2, =( (1<<4)|(0<<1)|(1<<0) ) @ Active low CE Control
 str r2, [r1, #oNFCONT]
 ldr r2, [r1, #oNFCONT]

 ldr r2, =(0x6) @ RnB Clear
 str r2, [r1, #oNFSTAT]
 ldr r2, [r1, #oNFSTAT]

 mov r2, #0xff @ RESET command
 strb r2, [r1, #oNFCMD]

 mov r3, #0 @ wait
nand1:
 add r3, r3, #0x1
 cmp r3, #0xa
 blt nand1

nand2:
 ldr r2, [r1, #oNFSTAT] @ wait ready
 tst r2, #0x4
 beq nand2

 ldr r2, [r1, #oNFCONT]
 orr r2, r2, #0x2 @ Flash Memory Chip Disable
 str r2, [r1, #oNFCONT]

 @ get read to call C functions (for nand_read())
 ldr sp, DW_STACK_START @ setup stack pointer
 mov fp, #0 @ no previous frame, so fp=0

 @ copy U-Boot to RAM
 ldr r0, =TEXT_BASE
 mov r1, #0x0
 mov r2, #LENGTH_UBOOT
 bl nand_read_ll
 tst r0, #0x0
 beq ok_nand_read

bad_nand_read:
loop2:
 b loop2 @ infinite loop
ok_nand_read:
 @ verify
 mov r0, #0
 ldr r1, =TEXT_BASE
 mov r2, #0x400 @ 4 bytes * 1024 = 4K-bytes
go_next:
 ldr r3, [r0], #4
 ldr r4, [r1], #4
 teq r3, r4
 bne notmatch
 subs r2, r2, #4
 beq stack_setup
 bne go_next

notmatch:
loop3:
 b loop3 @ infinite loop
#endif

#ifdef CONFIG_S3C2410

/* Offset */
#define oNFCONF 0x00
#define oNFCMD 0x04
#define oNFSTAT 0x10

 @ reset NAND
 mov r1, #NAND_CTL_BASE
 ldr r2, =0xf830 @ initial value
 str r2, [r1, #oNFCONF]
 ldr r2, [r1, #oNFCONF]
 bic r2, r2, #0x800 @ enable chip
 str r2, [r1, #oNFCONF]
 mov r2, #0xff  @ RESET command
 strb r2, [r1, #oNFCMD]

 mov r3, #0 @ wait
nand1:
 add r3, r3, #0x1
 cmp r3, #0xa
 blt nand1

nand2:
 ldr r2, [r1, #oNFSTAT] @ wait ready
 tst r2, #0x1
 beq nand2

 ldr r2, [r1, #oNFCONF]
 orr r2, r2, #0x800 @ disable chip
 str r2, [r1, #oNFCONF]

 @ get read to call C functions (for nand_read())
 ldr sp, DW_STACK_START @ setup stack pointer
 mov fp, #0 @ no previous frame, so fp=0

 @ copy U-Boot to RAM
 ldr r0, =TEXT_BASE
 mov r1, #0x0
 mov r2, #LENGTH_UBOOT
 bl nand_read_ll
 tst r0, #0x0
 beq ok_nand_read

bad_nand_read:
loop2:
 b loop2 @ infinite loop

ok_nand_read:
 @ verify
 mov r0, #0
 ldr r1, =TEXT_BASE
 mov r2, #0x400 @ 4 bytes * 1024 = 4K-bytes
go_next:
 ldr r3, [r0], #4
 ldr r4, [r1], #4
 teq r3, r4
 bne notmatch
 subs r2, r2, #4
 beq stack_setup
 bne go_next

notmatch:
loop3:
 b loop3 @ infinite loop

#endif
/***************** NAND BOOT end *************************************************/

(4)如果判断是在Nor  Flash中启动的话，那么nor  Flash搬移代码如下：

// copy U-Boot to RAM  form   Nor  Flash

/***************** NOR BOOT start *************************************************/
relocate:    /* relocate U-Boot to RAM     */
      /*********** CHECK_FOR_MAGIC_NUMBER***************/
 ldr r1, =(0xdeadbeef)
 cmp r0, r1
 bne loop3
      /*********** CHECK_FOR_MAGIC_NUMBER***************/
 adr r0, _start  /* r0 <- current position of code   */
 ldr r1, _TEXT_BASE  /* test if we run from flash or RAM */
 ldr r2, _armboot_start
 ldr r3, _bss_start
 sub r2, r3, r2  /* r2 <- size of armboot            */
 add r2, r0, r2  /* r2 <- source end address         */

copy_loop:
 ldmia r0!, {r3-r10}  /* copy from source address [r0]    */
 stmia r1!, {r3-r10}  /* copy to   target address [r1]    */
 cmp r0, r2   /* until source end addreee [r2]    */
 ble copy_loop
//#endif /* CONFIG_SKIP_RELOCATE_UBOOT */
/***************** NOR BOOT end********************************************/

 /* Set up the stack          */
stack_setup:
 ldr r0, _TEXT_BASE  /* upper 128 KiB: relocated uboot   */
 sub r0, r0, #CONFIG_SYS_MALLOC_LEN /* malloc area             */
 sub r0, r0, #CONFIG_SYS_GBL_DATA_SIZE /* bdinfo